Improved batch script

[NoobToolzz]

Not really an issue, just improved the batch script to search for 1v1.LOL\1v1_LOL.exe from the default Steam path (SteamLibrary\steamapps\common) in any of the users drives. Then it auto-launches the game and waits for 15 seconds before injecting the DLL (fixed the name to 1v1.lol.cheat.dll) and closes.

EDIT: Now it instantly proceeds to injecting if the game is already running.

@echo off
setlocal enabledelayedexpansion

set "game_exe_path="
set "game_folder=SteamLibrary\steamapps\common\1v1.LOL"

rem Set color attributes
set "color_yellow=0E"
set "color_green=0A"
set "color_reset=07"

echo Searching for the game...
color %color_yellow%

for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist "%%d:\%game_folder%\1v1_LOL.exe" (
        set "game_exe_path=%%d:\%game_folder%\1v1_LOL.exe"
        timeout /t 1 /NOBREAK >nul
        goto :GameFound
    )
)

:GameFound
if not defined game_exe_path (
    color %color_reset%
    echo Game not found on any drive.
    exit /b 1
)

color %color_yellow%
echo Checking if the game is already running...
timeout /t 1 /NOBREAK >nul

tasklist /FI "IMAGENAME eq 1v1_LOL.exe" 2>NUL | find /I /N "1v1_LOL.exe" >NUL
if "%ERRORLEVEL%"=="0" (
    color %color_green%
    echo Game is already running. Injecting...
    timeout /t 2 /NOBREAK >nul
    goto :Inject
) else (
    cls
    color %color_green%
    echo Launching game from: %game_exe_path%
    start "" "%game_exe_path%"
)

echo Sleeping for 15 seconds...
timeout /t 15 /NOBREAK >nul

:Inject
cls
color %color_green%
echo Injecting...
timeout /t 1 /NOBREAK >nul
smi.exe inject -p "1v1_LOL" -a "1v1.lol.cheat.dll" -n Loading -c Loader -m Load
echo Injected.

echo.
echo Closing in 5 seconds...
timeout /t 5 /NOBREAK >nul

color %color_reset%
exit /b 0

[CrispyyBaconx]

Wouldn't this be better as a pull req?

[NoobToolzz]

Wouldn't this be better as a pull req?

I wasn't bothered to clone the repo just to edit the README file.

[CrispyyBaconx]

Fair