关于批量下载

[haig233]

软件能否实现批量下载？ 例如把视频地址存在一个txt里一个一行 软件加某个参数，后面跟上txt路径，可以自动下载里面的所有视频

[RyanL-29]

https://github.com/RyanL-29/BBDown

我不知道我這個Fork 能不能滿足你, 我這個暫時是使用 bat script 實現自動化, 以及對部分功能進行了修改提高自動化的便利

[Hello-everybody]

大佬，怎样使用啊 批量下载

[daihxu]

不知道能不能帮到你

@echo off
title Crown
set "FileName=BBDown.exe"

for /f "tokens=2,*" %%i in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop"') do Set "desktop=%%j"
echo 您当前桌面路径是: %desktop%
if exist %desktop%\videos.txt (
  for /f "tokens=1,* delims=:" %%x in ('findstr /n ".*" videos.txt') do (if "%%x"=="1" set bbdown=%%y)
)

if exist %desktop%\videos.txt (
  echo %bbdown%|find /i "BBDown">nul && (
    echo 当前找到BBDown地址：%bbdown%
    for /f "skip=2" %%c in (%desktop%\videos.txt) do (
      echo 当前下载视频："%%c"
      start /wait /d "%bbdown%" cmd /c bbdown -mt -p all "%%c"
      choice /t 1 /d n /n >nul
    )
    echo.
    echo.
    echo 当前视频下载完成或您未填入url地址,请按随意键退出.
    echo 如果报错Object reference..一闪而过,请检查该视频是否还需B币购买.
    pause>nul
    exit
  ) || (
    echo 正在为您查找本机BBDown程序，请稍候...
    goto findFun
    exit
  )
) else (
  echo 第一次进入正在为您创建文本和查找本机BBDown程序.
  goto findFun
  pause
  exit
)

:findFun
for %%a in (C D E F) do (
  echo 当前查找中的盘符为:%%a
  if exist %%a:\ (
    for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo 查找到程序路径为:%%b
        echo %%~dpb > %desktop%\videos.txt
      )
    )
  )
)
echo https://www.bilibili.com/url/demo>>%desktop%\videos.txt
echo BBDown路径已为您写入videos.txt中,勿清除文本第一二行.
echo 且请按照txt中url demo填入需要下载视频地址,再重新运行该.bat.
start chrome "https://www.bilibili.com/"

pause
::@exit