平面桁架的静力分析

[blog-guang]

源码如下：

! 平面桁架的静力分析
FINISH
/CLEAR
/PREP7
!创建关键点
K,1
K,2,2
K,3,2,1
K,4,4,2
K,5,4
K,6,6
K,7,6,1
K,8,8
!创建线
L,1,2
L,2,3
L,3,4
L,4,5
L,5,6
L,6,7
L,7,8
L,1,3
L,2,5
L,4,7
L,6,8
L,3,5
L,5,7
!定义单元类型，实常数和材料属性
ET,1,LINK1
R,1,0.0144
MP,EX,1,8.5E9
MP,PRXY,1,0.2
!定义线属性，网格密度并划分网格：LATT, MAT, REAL, TYPE
LATT,1,1,1
LESIZE,ALL,,,1
LMESH,ALL
!施加约束条件和荷载
DK,1,UX,,,,UY
DK,8,UY
FK,1,FY,-1E4
FK,3,FY,-2E4
FK,4,FY,-1E4
!求解
/SOLU
ANTYPE,0
SOLVE
FINISH
!进入后处理
/POST1
PLDISP          !显示变形图
!显示关键点、线、面、体和节点的编号(0关闭，1打开)
/PNUM,KP,0  
/PNUM,LINE,0
/PNUM,AREA,0
/PNUM,VOLU,0
/PNUM,NODE,0
/PNUM,ELEM,1
/NUMBER,0               !0：编号和色彩同时显示，1:只显示色彩，不显示编号，2：只显示编号不显示色彩
!定义单元表
ETABLE,MFORCE,SMISC,1           !以杆单元的轴力(SMISC,1)为内容，定义单元表MFORCE
ETABLE,MSTRESS,LS,1             !以杆单元的轴向应力(LS,1)为内容，定义单元表MSTRESS
ETABLE,MSTRAIN,LEPEL,1          !以杆单元的轴向应变(LEPEL,1)为内容，定义单元表MSTRAIN
PRETAB                          !显示单元表
!绘制力素图形
PLLS,MFORCE,MFORCE,1
PLLS,MSTRESS,MSTRESS,1
PLLS,MSTRAIN,MSTRAIN,1
!显示结果并获得节点解
PRRSOL
MIDF = UY(NODE(4,0,0))