packaging for apt and pacman

[bexxmodd]

trafficstars

Now vizex is installable only through pypi package. If some is knowledgeable and can help with packaging for apt and pacman that will be great!

[yochananmarqos]

It's been in the AUR since last September. 😉 See #2

[bexxmodd]

yeah, good catch! completely forgot about the AUR package. But we still need for Debian

[perigoso]

If someone is willing to maintain the AUR package for me hit me up, for now its stuck on 2.0.3 sinca that was the last release on github, and I don't have time to move it over to pypi

[yochananmarqos]

@perigoso I just replied on the AUR page (now deleted), but now I'm thinking about what you said. Where are releases going to be? GitHub or PyPI? Either way, it's not hard to change the source.

This is my PKGBUILD right now. Please change the module name and include the license and requirements.txt in the PyPI tarball. I was going to create an issue, I guess I forgot:

pkgname=vizex
pkgver=2.0.5
pkgrel=1
pkgdesc="Visualize disk space and disk usage in your UNIX\Linux terminal"
arch=('any')
url="https://github.com/bexxmodd/vizex"
license=('MIT')
depends=('python-click' 'python-colored' 'python-pandas' 'python-psutil'
         'python-magic-ahupp' 'python-tabulate')
makedepends=('python-setuptools')
#checkdepends=('python-pytest')
_commit=d3e7de09767ffbc7cbb04efaec009d30f882b3bb
source=("https://pypi.org/packages/source/${pkgname:0:1}/$pkgname/$pkgname-$pkgver.tar.gz"
        "https://raw.githubusercontent.com/bexxmodd/vizex/$_commit/requirements.txt")
sha256sums=('1264820d82aaee52be258795ebfab3439be6aeec046af27ffb3bd8a11cf2cd47'
            '9efdfc25893d53699561a7ab87f8a48566a45f93d7ffe681749295a838280c2a')

prepare() {
  cd "$pkgname-$pkgver"

  # Proper module name
  find . -type f -exec sed -i "s|main|$pkgname|g" {} \;
  mv main "$pkgname"

  cp "$srcdir/requirements.txt" .
}

build() {
  cd "$pkgname-$pkgver"
  python setup.py build
}

#check() {
#  cd "$pkgname-$pkgver"
#  pytest
#}

package() {
  cd "$pkgname-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}

[bexxmodd]

I guess I'll do the GitHub release for 2.0.5 as well.

[bexxmodd]

I released latest version on PyPi and Github as well

[yochananmarqos]

That's great, but it's currently broken. See #41

[yochananmarqos]

@perigoso You can update the AUR package to 2.1.1c now:

pkgname=vizex
pkgver=2.1.1c
pkgrel=1
pkgdesc="Visualize disk space and disk usage in your UNIX\Linux terminal"
arch=('any')
url="https://github.com/bexxmodd/vizex"
license=('MIT')
depends=('python-click' 'python-colored' 'python-pandas' 'python-psutil'
         'python-magic-ahupp' 'python-tabulate')
makedepends=('python-setuptools')
#checkdepends=('python-pytest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('7081af2197a98c5b9871c62b56c8c16e19f62e022221f1759793f615481ce8f6')

build() {
  cd "$pkgname-$pkgver"
  python setup.py build
}

#check() {
#  cd "$pkgname-$pkgver"
#  pytest
#}

package() {
  cd "$pkgname-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}